Default Website Stopping

Question: - SBS 2003, I am trying to setup a Droid with ActiveSync. After inputting the setting to the phone I could not connect. The default website on the server was stopped. I started it and the phone connected without any problems. after about 2 minutes the website stopped again. I cannot seem to get it to stay running for more then a couple of minutes.


Answer: - You may need to enable in the user's exchange account features. The two features that must be enabled are "User Initiated Synchronization" and "Up-to-date Notification". These features can be found in Active Directory. You need to log-on to the Exchange server, open an MMC to Active Directory users and Computers and then Enable these features. Then try to enable the website and Droid.

List Web sites on IIS 5.0 NT 4.0

Question: -  I need a help to list the created web sites' name on txt configured on an IIS server with NT4.0, currently I can only list the SiteID with adsutil.vbs, but it would not list the Web sites' name.
i.e:

Server
Default web site
Administration web site
website1.ve
website3.com

Any suggestions are much appreciated.

Solution : - 
You may use Script for that

OPTION EXPLICIT

DIM strServer, strServerType, strServerMetaType
DIM objService

strServer = "localhost"
strServerType = "Web"
strServerMetaType = "W3SVC"

IF WScript.Arguments.Length >= 1 THEN
    strServer = WScript.Arguments( 0 )
END IF

IF WScript.Arguments.Length = 2 THEN
    strServerType = WScript.Arguments( 1 )

    IF UCASE( strServerType ) = "FTP" THEN
        strServerType = "Ftp"
        strServerMetaType = "MSFTPSVC"
    ELSE
        strServerType = "Web"
        strServerMetaType = "W3SVC"
    END IF
END IF

WScript.Echo "Enumerating " & strServerType & "sites on " & strServer & VbCrLf
SET objService = GetObject( "IIS://" & strServer & "/" & strServerMetaType )
EnumServersites objService


SUB EnumServersites( objService )
    DIM objServer, strBindings

    FOR EACH objServer IN objService
        IF objServer.Class = "IIs" & strServerType & "Server" THEN
            WScript.Echo _
                "Site ID = " & objServer.Name & VbCrLf & _
                "Comment = """ & objServer.ServerComment & """ " & VbCrLf & _
                "State   = " & State2Desc( objServer.ServerState ) & VbCrLf & _
                "LogDir  = " & objServer.LogFileDirectory & _
                ""

            ' Enumerate the HTTP bindings (ServerBindings) and
            ' SSL bindings (SecureBindings) for HTTPS only
            strBindings = EnumBindings( objServer.ServerBindings )

            IF strServerType = "Web" THEN
                strBindings = strBindings & _
                EnumBindings( objServer.SecureBindings )
            END IF

            IF NOT strBindings = "" THEN
                WScript.Echo "IP Address" & VbTab & _
                             "Port" & VbTab & _
                             "Host" & VbCrLf & _
                             strBindings
            END IF
        END IF
    NEXT

END SUB

FUNCTION EnumBindings( objBindingList )
    DIM i, strIP, strPort, strHost
    DIM reBinding, reMatch, reMatches
    SET reBinding = NEW RegExp
    reBinding.Pattern = "([^:]*):([^:]*):(.*)"

    FOR i = LBOUND( objBindingList ) TO UBOUND( objBindingList )
        ' objBindingList( i ) is a string looking like IP:Port:Host
        SET reMatches = reBinding.Execute( objBindingList( i ) )
        FOR EACH reMatch in reMatches
            strIP = reMatch.SubMatches( 0 )
            strPort = reMatch.SubMatches( 1 )
            strHost = reMatch.SubMatches( 2 )

            ' Do some pretty processing
            IF strIP = "" THEN strIP = "All Unassigned"
            IF strHost = "" THEN strHost = "*"
            IF LEN( strIP ) < 8 THEN strIP = strIP & VbTab

            EnumBindings = EnumBindings & _
                           strIP & VbTab & _
                           strPort & VbTab & _
                           strHost & VbTab & _
                           ""
        NEXT

        EnumBindings = EnumBindings & VbCrLf
    NEXT

END FUNCTION

FUNCTION State2Desc( nState )
    SELECT CASE nState
    CASE 1
        State2Desc = "Starting (MD_SERVER_STATE_STARTING)"
    CASE 2
        State2Desc = "Started (MD_SERVER_STATE_STARTED)"
    CASE 3
        State2Desc = "Stopping (MD_SERVER_STATE_STOPPING)"
    CASE 4
        State2Desc = "Stopped (MD_SERVER_STATE_STOPPED)"
    CASE 5
        State2Desc = "Pausing (MD_SERVER_STATE_PAUSING)"
    CASE 6
        State2Desc = "Paused (MD_SERVER_STATE_PAUSED)"
    CASE 7
        State2Desc = "Continuing (MD_SERVER_STATE_CONTINUING)"
    CASE ELSE
        State2Desc = "Unknown state"
    END SELECT

END FUNCTION

Title: Why are my user now being prompted for a login after Front Page Server Extensions were installed?

I have a development intranet server using windows authentication running on iis7.  Front Page server Extensions were install and then fully uninstalled. Now each time a users pulls up the main page they are prompted for a login.

How do I fix this?

Thank you.

Suggested Solution : - 
Please check the security permissions for the website. What security permissions are you using?
Only Anonymous  - It won't ask for login prompt
Basic Auth -> it will ask for login prompt
Integrated security auth -> if users are in same domain , it wont ask for login prompt

How is your server setup? Is it in domain? or standalone? Please review your security permissions.
Solution : - Web site -> properties -> Security ->  Select User group -> Advanced -> Select edit -> clicked “Replace all existing inheritable permissions on all descendants with inheritable permissions from this object” 
-> Apply